' ランニングテストプログラム(VBS)

Dim ctrl	' コントローラオブジェクト
Dim arm		' ロボットオブジェクト
Dim P1		' 変数オブジェクト(P1)
Dim P2		' 変数オブジェクト(P2)
Dim P3		' 変数オブジェクト(P3)
Dim P4		' 変数オブジェクト(P4)

Sub Main
   Dim i
   ' 初期化
   Initialize
   ' ポジションデータセット
   SetPositionData
   ' 動作を無限回繰り返す
   i = 0
   Do
      PickAndPlace
      i = i+1
      vars(1).Value = i	' 動作回数を保存
   Loop
End Sub

Sub Initialize
   Set ctrl = cao.AddController("", "CaoProv.DENSO.NetwoRC", "", "Conn=eth:192.168.0.1")

   Set P1 = Ctrl.AddVariable("P1")
   Set P2 = Ctrl.AddVariable("P2")
   Set P3 = Ctrl.AddVariable("P3")
   Set P4 = Ctrl.AddVariable("P4")

   Set arm = Ctrl.AddRobot("vs")
   arm.SPEED -1, 100	 '-1：手先速度
End Sub

Sub SetPositionData
   P1.Value = ToR4(Array(271.48, -207.73, 400.59, 177.11, 3.97, 140.97,5))
   P2.Value = ToR4(Array(271.48, -212.73, 33.59, 177.11, 3.97, 140.97,5))
   P3.Value = ToR4(Array(271.48, 202.27, 400.59, 177.11, 3.97, 140.97,5))
   P4.Value = ToR4(Array(271.48, 202.27, 33.59, 177.11, 3.97, 140.97,5))
End Sub

Sub PickAndPlace
   arm.MOVE 1, "P1"
   arm.MOVE 2, "P2"
   Ext.DELAY 10
   arm.MOVE 2, "P1"
   arm.MOVE 1, "P3"
   arm.MOVE 2, "P4"
   arm.MOVE 1, "P3"
End Sub

Function ToVar(vntSrc)
   ToVar = DAT.ChangeType(vntSrc, 12)	' VT_VARIANT = 12
End Function

Function ToR4(vntSrc)
   ToR4= DAT.ChangeType(vntSrc, 4)	' VT_R4 = 4
End Function