' IPAddress
Const IPAddress = "127.0.0.1"

' Provider Name
' Const ProviderName = "caoProv.OpenCV"		' EVP1
Const ProviderName = "caoProv.DENSO.RIL"		' EVP2

' Save Folder
Const FolderPath = "Path=C:\Temp"


Sub Main
	' Imaging
	Dim caoCtrl	' Image Controller object
	Dim caoFile	' File object
	Dim caoMaxSize	' Value object
	
	' File
	Dim caoCtrlLF		' LocalFileProvider
	Dim caoFileFolder	' Folder object
	Dim caoFileImage	' File object
	
	Dim lCnt			' Counter
	Dim strFolder ' Folder name
	Dim strFileName ' FileName

	dbg.Output "Start"
	
	' Connect RC8 Imaging library
	set caoCtrl = cao.Addcontroller("ocv", "caoProv.b-CAP", "", "Provider=" & ProviderName & ", timeout=2000, server=" & IPAddress )
	set caoFile = caoCtrl.AddFile("*", "ID=11")
	set caoMaxSize = caoCtrl.AddVariable("@IMG_MAX")

	' Connect LocalFile Provider
	strFolder  = "Images_" & Now
	strFolder = Replace(strFolder, "/", "")
	strFolder = Replace(strFolder, ":", "")
	strFolder = Replace(strFolder, " ", "_")
	dbg.Output strFolder

	set caoCtrlLF = cao.AddController("LocalFile", "CaoProv.LocalFile", "", "")
	set caoFileFolder = caoCtrlLF.AddFile(strFolder, "@Create=2," & FolderPath)	

	For lCnt = 11 to caoMaxSize.Value
		' ID change
		caoFile.ID = lCnt
		
		if not caoFile.Execute("IsEmpty") Then
			' Make file name
			strFileName = CStr(lCnt) & ".bmp"
			dbg.Output strFileName

			' Make image file
			set caoFileImage = caoFileFolder.AddFile(strFileName, "@Create=1")
			caoFileImage.Value = caoFile.Value
			
			' delte file object
			caoFileFolder.Files.Remove caoFileImage.Index
			set caoFileImage = Nothing
		end if
	Next
	
	dbg.Output "End"
End Sub